cpp-equiv/CMakeLists.txt at main · Ahajha/cpp-equiv · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
cmake_minimum_required(VERSION 3.14)

project(
    cpp-equiv
    VERSION 0.0.1
    DESCRIPTION "A C++20 equivalence relation library"
    HOMEPAGE_URL "https://github.com/Ahajha/cpp-equiv"
    LANGUAGES CXX
)

# ---- Warning guard ----

# Protect dependents from this project's warnings if the guard isn't disabled
set(cpp-equiv_warning_guard SYSTEM)
if(cpp-equiv_INCLUDE_WITHOUT_SYSTEM)
  set(cpp-equiv_warning_guard "")
endif()

# ---- Declare library ----

add_library(cpp-equiv INTERFACE)
add_library(cpp-equiv::cpp-equiv ALIAS cpp-equiv)

target_include_directories(
    cpp-equiv
    ${cpp-equiv_warning_guard}
    INTERFACE
    "$<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>"
)

target_compile_features(cpp-equiv INTERFACE cxx_std_20)

# ---- Install ----

include(CMakePackageConfigHelpers)
include(GNUInstallDirs)

set(cpp-equiv_include_directory "${CMAKE_INSTALL_INCLUDEDIR}/cpp-equiv")

install(
    DIRECTORY "${PROJECT_SOURCE_DIR}/include/"
    DESTINATION "${cpp-equiv_include_directory}"
    COMPONENT cpp-equiv_Development
)

install(
    TARGETS cpp-equiv
    EXPORT cpp-equiv-targets
    INCLUDES DESTINATION "${cpp-equiv_include_directory}"
)

write_basic_package_version_file(
    cpp-equiv-config-version.cmake
    COMPATIBILITY SameMajorVersion
    ARCH_INDEPENDENT
)

set(cpp-equiv_install_cmakedir "${CMAKE_INSTALL_LIBDIR}/cmake/cpp-equiv")

install(
    FILES "${PROJECT_BINARY_DIR}/cpp-equiv-config-version.cmake"
    DESTINATION "${cpp-equiv_install_cmakedir}"
    COMPONENT cpp-equiv_Development
)

install(
    EXPORT cpp-equiv-targets
    FILE cpp-equiv-config.cmake
    NAMESPACE cpp-equiv::
    DESTINATION "${cpp-equiv_install_cmakedir}"
    COMPONENT cpp-equiv_Development
)

if(CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
  include(CPack)
endif()