BedWarsLanguage/build.gradle.kts at 0.3.x · ScreamingSandals/BedWarsLanguage · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
import org.screamingsandals.gradle.builder.configureJavac
import org.screamingsandals.bedwars.lang.tasks.ValidateJsonTask
import org.screamingsandals.bedwars.lang.tasks.GenerateBuildInfoTask
import org.screamingsandals.bedwars.lang.tasks.GenerateLangKeysTask
import org.screamingsandals.gradle.builder.configureSourcesJar
import org.screamingsandals.gradle.builder.setupMavenPublishing
import org.screamingsandals.gradle.builder.setupMavenRepositoriesFromProperties

plugins {
    java
    alias(libs.plugins.screaming.plugin.builder)
}

defaultTasks("clean", "build")

val buildInfoDir = project.layout.buildDirectory.dir("generated/buildinfo")
val buildLangKeysDir = project.layout.buildDirectory.dir("generated/sources/langkeys")
val projectBuildNumber = providers.environmentVariable("BUILD_NUMBER").orElse("custom")

tasks.register<ValidateJsonTask>("validateJson") {
    group = "build"
    description = "Validate all JSON resource files."

    jsonFiles.from(fileTree("src/main/resources/languages") { include("*.json") })
}

tasks.register<GenerateBuildInfoTask>("generateBuildInfoFile") {
    group = "build"

    languageFiles.from(fileTree("src/main/resources/languages") { include("*.json") })
    outputDir.set(buildInfoDir)

    version.set(project.version.toString())
    buildNumber.set(projectBuildNumber)
}

tasks.register<GenerateLangKeysTask>("generateLangKeys") {
    group = "build"
    description = "Generate LangKeys.java from language_en-US.json"

    dependsOn("validateJson")

    packageName.set(providers.gradleProperty("langkeys.package"))
    className.set(providers.gradleProperty("langkeys.class"))

    inputJson.set(layout.projectDirectory.file("src/main/resources/languages/language_en-US.json"))

    outputJava.set(
        buildLangKeysDir
            .map { it.dir(packageName.get().replace(".", "/")) }
            .map { it.file("${className.get()}.java") }
    )
}

sourceSets {
    main {
        java {
            srcDir(buildLangKeysDir)
        }
    }
}

tasks.jar {
    dependsOn("generateBuildInfoFile")
    from(buildInfoDir)
}

configureJavac(JavaVersion.VERSION_11)
setupMavenPublishing {
    pom {
        name.set("BedWars Language")
        description.set("Translation for BedWars Plugin")
        url.set("https://github.com/ScreamingSandals/BedWarsLanguage")
        licenses {
            license {
                name.set("GNU Lesser General Public License v3.0")
                url.set("https://github.com/ScreamingSandals/BedWarsLanguage/blob/0.3.x/LICENSE")
            }
        }

        properties.put("build.number", projectBuildNumber)
    }
}
setupMavenRepositoriesFromProperties()

tasks.compileJava {
    dependsOn("generateLangKeys")
}

tasks.build {
    dependsOn("validateJson")
}