add on_join_table_conflict to repo.insert

Author: greg-rychlewski

lib/ecto/association.ex

@@ -1554,8 +1554,9 @@ defmodule Ecto.Association.ManyToMany do
           owner_value = dump!(:insert, join_through, owner, owner_key, adapter)
           related_value = dump!(:insert, join_through, related, related_key, adapter)
           data = %{join_owner_key => owner_value, join_related_key => related_value}
+          join_table_opts = put_join_table_on_conflict!(opts)
 
-          case insert_join(join_through, refl, parent_changeset, data, opts) do
+          case insert_join(join_through, refl, parent_changeset, data, join_table_opts) do
             {:error, join_changeset} ->
               {:error,
                %{
@@ -1592,6 +1593,20 @@ defmodule Ecto.Association.ManyToMany do
             "an atom (representing a schema) or a string (representing a table)"
   end
 
+  defp put_join_table_on_conflict!(opts) do
+    case Keyword.fetch(opts, :on_join_table_conflict) do
+      {:ok, on_conflict} when on_conflict in [:raise, :nothing] ->
+        Keyword.put(opts, :on_conflict, on_conflict)
+
+      :error ->
+        opts
+
+      {:ok, other} ->
+        raise ArgumentError,
+              "expected `:on_join_table_conflict` to be one of `:raise` or `:nothing`, got: `#{inspect(other)}`"
+    end
+  end
+
   defp insert_join?(%{action: :insert}, _, _field, _related_key), do: true
   defp insert_join?(_, %{action: :insert}, _field, _related_key), do: true
 

lib/ecto/repo.ex

@@ -1905,6 +1905,12 @@ defmodule Ecto.Repo do
       are not updated in order to enable optimizations such as HOT updates in PostgreSQL.
       Defaults to `true`.
 
+    * `:on_join_table_conflict` - If a many-to-many association is part of the insert,
+      Ecto will automatically try to create the corresponding entry in the association's
+      `:join_through` table. This option allows you to configure the conflict resolution
+      behaviour when the record already exists. The allowed values are `:raise` (the default)
+      or `:nothing`.
+
     * `:stale_error_field` - The field where stale errors will be added in
       the returning changeset. This option can be used to avoid raising
       `Ecto.StaleEntryError`.

lib/ecto/repo/schema.ex

@@ -1163,7 +1163,7 @@ defmodule Ecto.Repo.Schema do
   defp assoc_opts([], _opts), do: []
 
   defp assoc_opts(_assocs, opts) do
-    Keyword.take(opts, [:timeout, :log, :telemetry_event, :prefix, :allow_stale])
+    Keyword.take(opts, [:timeout, :log, :telemetry_event, :prefix, :allow_stale, :on_join_table_conflict])
   end
 
   defp process_parents(changeset, user_changeset, assocs, reset_assocs, adapter, opts) do

test/ecto/repo/many_to_many_test.exs

@@ -107,10 +107,45 @@ defmodule Ecto.Repo.ManyToManyTest do
     assert assoc.inserted_at
     assert_received {:insert, _}
 
-    assert_received {:insert_all, %{source: "schemas_assocs"},
+    assert_received {:insert_all, %{source: "schemas_assocs", on_conflict: {:raise, [], []}},
+                     [[my_assoc_id: 1, my_schema_id: 1]]}
+  end
+
+  test "handles assocs on insert with on_join_table_conflict" do
+    sample = %MyAssoc{x: "xyz"}
+
+    changeset =
+      %MySchema{}
+      |> Ecto.Changeset.change()
+      |> Ecto.Changeset.put_assoc(:assocs, [sample])
+
+    schema = TestRepo.insert!(changeset, on_join_table_conflict: :nothing)
+    [assoc] = schema.assocs
+    assert assoc.id
+    assert assoc.x == "xyz"
+    assert assoc.inserted_at
+    assert_received {:insert, _}
+
+    assert_received {:insert_all, %{source: "schemas_assocs", on_conflict: {:nothing, [], []}},
                      [[my_assoc_id: 1, my_schema_id: 1]]}
   end
 
+  test "on_join_table_conflict only accepts :raise or :nothing" do
+    sample = %MyAssoc{x: "xyz"}
+
+    changeset =
+      %MySchema{}
+      |> Ecto.Changeset.change()
+      |> Ecto.Changeset.put_assoc(:assocs, [sample])
+
+    msg =
+      "expected `:on_join_table_conflict` to be one of `:raise` or `:nothing`, got: `:replace_all`"
+
+    assert_raise ArgumentError, msg, fn ->
+      TestRepo.insert!(changeset, on_join_table_conflict: :replace_all)
+    end
+  end
+
   test "handles assocs on insert preserving parent schema prefix" do
     sample = %MyAssoc{x: "xyz"}