CMakeLists.txt

cmake_minimum_required(VERSION 3.22)
project(MASS VERSION 1.0.1)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

# Static CRT: embed the runtime so Kontakt's msvcp140.dll conflict can't reach us
set(CMAKE_MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>")

add_subdirectory("E:/JUCE" JUCE)

juce_add_plugin(MASS
    VERSION                     1.0.1
    COMPANY_NAME                "Mantis Vex"
    COMPANY_WEBSITE             "https://mantisvex.com"
    COMPANY_EMAIL               "mantisvex@gmail.com"
    PLUGIN_MANUFACTURER_CODE    MtVx
    PLUGIN_CODE                 Mass
    FORMATS                     VST3
    PRODUCT_NAME                "MASS"
    DESCRIPTION                 "Adaptive harmonic density processor"
    BUNDLE_ID                   "com.mantisvex.mass"
    IS_SYNTH                    FALSE
    NEEDS_MIDI_INPUT            FALSE
    NEEDS_MIDI_OUTPUT           FALSE
    IS_MIDI_EFFECT              FALSE
    EDITOR_WANTS_KEYBOARD_FOCUS FALSE
    VST3_CATEGORIES             "Fx" "Dynamics"
)

target_sources(MASS PRIVATE
    Source/PluginProcessor.cpp
    Source/PluginEditor.cpp
)

juce_add_binary_data(MASS_BinaryData SOURCES Assets/mantisvex.jpg)

target_include_directories(MASS PRIVATE Source DSP)

target_compile_definitions(MASS PUBLIC
    JUCE_WEB_BROWSER=0
    JUCE_USE_CURL=0
    JUCE_VST3_CAN_REPLACE_VST2=0
    JUCE_DISPLAY_SPLASH_SCREEN=0
    JUCE_REPORT_APP_USAGE=0
)

target_link_libraries(MASS PRIVATE
    MASS_BinaryData
    juce::juce_audio_utils
    juce::juce_dsp
    juce::juce_graphics
    juce::juce_gui_basics
    juce::juce_core
    PUBLIC
    juce::juce_recommended_config_flags
    juce::juce_recommended_lto_flags
    juce::juce_recommended_warning_flags
)

# Auto-deploy to a VST3 folder after every build (flat-file format, no admin required).
# Override locally with: cmake -B build -DVST3_DEPLOY_DIR="X:/path/to/your/VST3"
set(VST3_DEPLOY_DIR "$ENV{USERPROFILE}/VST3" CACHE PATH "Folder to copy the built MASS.vst3 into")
add_custom_command(TARGET MASS_VST3 POST_BUILD
    COMMAND ${CMAKE_COMMAND} -E copy_if_different
        "$<TARGET_FILE:MASS_VST3>"
        "${VST3_DEPLOY_DIR}/MASS.vst3"
    COMMENT "Deploying MASS.vst3 to ${VST3_DEPLOY_DIR}"
)