nixpkgs/pkgs/applications/science/logic/abella/default.nix at ec5e8f914cdfdd721020e09578b5ac344bc140cc · ryand56/nixpkgs · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
{
  lib,
  stdenv,
  fetchurl,
  rsync,
  ocamlPackages,
  dune,
}:

stdenv.mkDerivation (finalAttrs: {
  pname = "abella";
  version = "2.0.8";

  src = fetchurl {
    url = "http://abella-prover.org/distributions/abella-${finalAttrs.version}.tar.gz";
    sha256 = "sha256-80b/RUpE3KRY0Qu8eeTxAbk6mwGG6jVTPOP0qFjyj2M=";
  };

  strictDeps = true;

  nativeBuildInputs = [
    rsync
    dune
  ]
  ++ (with ocamlPackages; [
    ocaml
    menhir
    findlib
  ]);
  buildInputs = with ocamlPackages; [
    cmdliner
    yojson
  ];

  installPhase = ''
    mkdir -p $out/bin
    rsync -av _build/default/src/abella.exe    $out/bin/abella

    mkdir -p $out/share/emacs/site-lisp/abella/
    rsync -av emacs/    $out/share/emacs/site-lisp/abella/

    mkdir -p $out/share/abella/examples
    rsync -av examples/ $out/share/abella/examples/
  '';

  meta = {
    description = "Interactive theorem prover";
    mainProgram = "abella";
    longDescription = ''
      Abella is an interactive theorem prover based on lambda-tree syntax.
      This means that Abella is well-suited for reasoning about the meta-theory
      of programming languages and other logical systems which manipulate
      objects with binding.
    '';
    homepage = "https://abella-prover.org";
    license = lib.licenses.gpl3;
    maintainers = [ lib.maintainers.bcdarwin ];
    platforms = lib.platforms.unix;
  };
})