Android-Extensions/test/build.gradle at 74364187965048743c3239cb12694dc648650f96 · tunjid/Android-Extensions · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
apply from: "${project.rootDir}/androidLib.gradle"

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])

    implementation parent.ext.kotlin
    implementation parent.ext.appCompat
    implementation parent.ext.recyclerView

    implementation 'junit:junit:4.13.2'
    implementation 'org.hamcrest:hamcrest-library:2.2'
    implementation parent.ext.mockitoAndroid

    def androidTestExclusions = { lib, pairs ->
        implementation(lib) {
            pairs.each { exclude group: "${it.first}", module: "${it.second}" }
        }
    }

    List exclusions = [
            new Tuple2('androidx.appcompat', 'appcompat'),
            new Tuple2('androidx.core', 'core'),
            new Tuple2('androidx.activity', 'activity'),
            new Tuple2('androidx.fragment', 'fragment'),
            new Tuple2('androidx.loader', 'loader'),
            new Tuple2('androidx.recyclerview', 'recyclerview'),
            new Tuple2('androidx.viewpager2', 'viewpager2'),
            new Tuple2('androidx.savedstate', 'savedstate'),
            new Tuple2('androidx.lifecycle', 'lifecycle-livedata'),
            new Tuple2('androidx.lifecycle', 'lifecycle-common'),
            new Tuple2('androidx.lifecycle', 'lifecycle-viewmodel'),
            new Tuple2('androidx.lifecycle', 'lifecycle-livedata-core'),
            new Tuple2('androidx.lifecycle', 'lifecycle-runtime'),
            new Tuple2('androidx.arch.core', 'core-runtime'),
            new Tuple2('com.google.android.material', 'material')
    ]

    androidTestExclusions('androidx.test:runner:1.3.0', exclusions)
    androidTestExclusions('androidx.test:rules:1.3.0', exclusions)
    androidTestExclusions('androidx.test.espresso:espresso-core:3.3.0', exclusions)
    androidTestExclusions('androidx.test.espresso:espresso-contrib:3.5.1', exclusions)
    androidTestExclusions('androidx.test.espresso:espresso-intents:3.3.0', exclusions)
}